loadVariables()

Доступность

Flash Player 4; функциональность изменилось, начиная с Flash Player 7.

Синтаксис

loadVariables (url:String , target:Object [, variables:String]) : Void

Параметры

url Абсолютный или относительный URL, по которому необходимо получить переменные.. Если SWF файл запущен в браузере, url должен указывать на тот же домен, что и SWF file; смотри раздел Описание для более подробной информации.

target Мувиклип, в который загружаются данные.

variables Необязательный параметр, определяющий HTTP метод передачи переменных. Параметр должен иметь значение GET или POST. Если переменные отправлять не нужно, опустите этот параметр. Метод GET присоединяет переменные в конец URL и используется для небольшого числа переменных. Метод POST передает переменные в HTTP заголовке и используется для большого числа переменных.

Возвращает

Ничего.

Описание

Функция; получает данные из внешнего файла, например, читает данные из текстового файла или получает данные, выводимые ColdFusion, CGI , Active Server Pages (ASP), PHP или Perl скриптом и сохраняет переменные в указанном мувиклипе. Функция может использоваться для обновления данных.

Текст, получаемый по указанному URL, должен иметь стандартный MIME формат application/x-www-form-urlencoded (стандартный формат, используемый CGI скриптами). Загружено может быть любое число переменных. Например, следующая строка определяет несколько переменных:

company=Macromedia&address=600+Townsend&city=San+Francisco&zip=94103

В SWF файлах, проигрываемых во Flash Player версии более ранней, чем 7, url должен иметь тот же над-домен, что и SWF файл, загружающий данные. Над-домен получается путем удаления самой левой части из URL. Например, SWF файл по адресу www.someDomain.com может загружать переменные из домена store.someDomain.com, потому что оба файла находятся в одном над-домене someDomain.com.

В SWF файлах, проигрываемых во Flash Player 7 или более поздней версии, url должен указывать точно на тот же домен, что и SWF файл, в который происходит загрузка (смотри "Особенности безопасности во Flash Player" в Использовании ActionScript во Flash). Например, SWF файл, находящийся в домене www.someDomain.com может загружать данные только из источников в www.someDomain.com. Если Вы хотите загружать данные из другого домена, Вы можете поместить файл кросс-доменных политик (cross-domain policy file) на сервере, откуда производится загрузка. Для более подробной информации смотри "О кросс-доменной загрузке данных" в Использовании ActionScript во Flash.

Если Вы хотите загрузить данные на уровень, используйте loadVariablesNum()вместо loadVariables().

Пример

В следующем примере данные загружаются из текстового файла params.txt в мувиклип target_mc, динамически созданный при помощи createEmptyMovieClip(). Функция setInterval() отслеживает процесс загрузки. Скрипт проверяет окончание загрузки по значению переменной done.

this.createEmptyMovieClip("target_mc", this.getNextHighestDepth());
loadVariables("params.txt", target_mc);
function checkParamsLoaded() {
  if (target_mc.done == undefined) {
    trace("Еще не загрузилось.");
  } else {
    trace("Загрузилось. Очищаем интервал..");
    trace("-------------");
    for (i in target_mc) {
      trace(i+": "+target_mc[i]);
    }
    trace("-------------");
    clearInterval(param_interval);
  }
}
var param_interval = setInterval(checkParamsLoaded, 100);
// params.txt содержит следующий текст:
var1="hello"&var2="goodbye"&done="done"

См. также

loadVariablesNum(), loadMovie(), loadMovieNum(), getURL(), MovieClip.loadMovie(), MovieClip.loadVariables(), LoadVars.load()

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление